Format spec.

<data>         ::= "#", [<attacker>], [<defender>]


<attacker>     ::= "a:", <race>, <units> [, <upgrades>] [, <raid-mark>] [, <population>] [, <cata-targets>] [, <hero>] [, <plus-stat>] [, <big-party>] [, <brewery>], "#"
<defender>     ::= "d:", <race> [, <population>] [, <wall>] [, <residence>] [, <stonemason>] [, <traps>] [, <plus-stat>] [, <big-party>], (<def-side>){1,}, "#"
      (* here race is attribute of place of battle, affects type of wall *)


<def-side>     ::= ";", <race>, <units> [, <upgrades>] [, <hero>]
      (* here race is attribute of units *)

<race>         ::= "r", <digit>
      (* 1 - romans, 2 - teutons, 3 - gauls; off:/4 - natar/; def:/4 - nature, 5 - natar/ *)

<units>        ::= "u", <number-array>
      (* examples: "u10,,,10", "u,,100" *)
<upgrades>     ::= "U", ( <number-array> | "!", <number> )
      (* notice compact indexing (50 imps @10 up level are "u,,50U10") and CAPITAL "U" *)
      (* "!U<number>" means, that all units have the same upgrade level *)
<raid-mark>    ::= "R"           (* is set, when attck type is raid *)
<population>   ::= "p", <number> (* population of whole account *)
<wall>         ::= "w", <number> (* wall level *)
<residence>    ::= "R", <number> (* residence/palace level *)
<stonemason>   ::= "s", <number> (* stonemason level *)
<traps>        ::= "t", <number> (* traps amount *)
<plus-stat>    ::= "P"           (* plus-offense or plus-defense *)
<brewery>      ::= "B", <number> (* brewery level celebration *)
<big-party>    ::= "C"           (* big celebration from any side *)
<cata-targets> ::= "b", <number> [, <number>]
      (* levels of targeted buildings *)


<hero>         ::= "h" [, <digit>, ",", <number>, ",", <number>, ",", <number>]
      (* unit-type(0-4), self skill(0-100), bonus skill(0-100), health(0-100) *)


<number-array> ::= <number-null> [, ",", <number-null>]{0,9}
<number>       ::= <digit>{1,} [, <multiplier>]
<number-null>  ::= <digit>{0,} (* empty string considered as zero *)


<digit>        ::= ( "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9" )
<multiplier>   ::= ( "K" | "M" )
      (* K is for 1000 and M is for 1000000 *)